Jack Onil Bab-7 Membuat Latar Belakang

Program pertama yang harus dibuat setelah layout game selesai dirancang adalah menampilkan latar belakang atau background.

Download source code disini

Untuk membuat gambar latar belakang sangat mudah, karena Anda telah belajar proses render yang ogut terangkan sebelumnya.

Latar belakang game dibuat dengan cara mengisi screen game dengan tekstur tertentu. Untuk itu dibutuhkan sebuah tekstur dan sebuah persegipanjang yang akan ogut gunakan untuk mengisi screen game.

Pertama load sebuah tekstur.

Public Function Load_All_texture() As Boolean

    If Not Create_Texture(Text_BG, _
                "\Texture\BG\BG.bmp") Then
                
        Load_All_texture = False
        Exit Function
        
    End If
                   
    'jika semua berjalan baik return true
    Load_All_texture = True
End Function

Buat sebuah persegipanjang yang menutupi screen game, lalu render persegipanjang tersebut.

Public Text_BG As GLuint

Public Sub Display_BG()
    glBindTexture glTexture2D, Text_BG
    glBegin bmPolygon
        glTexCoord2f 0#, 0: glVertex2i -Xmax, -Ymax
        glTexCoord2f 1#, 0: glVertex2i Xmax, -Ymax
        glTexCoord2f 1#, 1#: glVertex2i Xmax, Ymax
        glTexCoord2f 0#, 1#: glVertex2i -Xmax, Ymax
    glEnd
End Sub

Panggil sub yang kita buat di atas pada main looping, sehingga isi dari main program dan sub Render_Objek menjadi sebagai berikut.

'Sub utama yang dijalankan paling awal
'oleh Visual Basic
Private Sub Main()
    Dim My_Form As Form
     
    Selesai = False
    
    Set My_Form = New Form1
        
    'jika form untuk OpenGL gagal dibuat
    'maka program akan berhenti
    If Not Create_OpenGL(My_Form, _
                        My_hrc, _
                        Xmax, Ymax) Then
        Selesai = True
    End If
    
    Inisialisasi_OpenGL
    
    'load semua tekstur sebelum main looping
    'jika proses ini gagal program akan berhenti
    If Not Load_All_texture() Then
        Selesai = True
    End If
        
    'main looping
    Do While Not Selesai
    
        'deteksi keyboard dan proses render
        'diulang hingga selesai
        Keyboard_Ditekan
        Render_Objek
        
        'swapbuffer dan doevent
        SwapBuffers (My_Form.hDC)
        DoEvents
    Loop
    
    Unload My_Form
    Closing_OpenGL My_hrc
        
    Set My_Form = Nothing
    End  'quit program
    
End Sub

Private Sub Render_Objek()
    Dim i As Integer
    glClear clrColorBufferBit Or _
            clrDepthBufferBit
    glLoadIdentity
    
    'Tampilkan Latar belakang game di sini
    Display_BG
    
End Sub

Salam Jack Onil


Heriady
heriady.yoh@gmail.com

Download source code ada disini

Artikel terkait

Membuat Game dengan VB 6 Klik link ini untuk menuju ke artikel